Skript Paylaşımı /xpsakla - Faction sunucuları için ideal bir sistem

on load:
    delete {sohbetxp::*}

command /xpsakla:
    trigger:
        open virtual chest inventory with size 5 named "XP saklayalım mı?" to player
        make gui slot 10, 11, 12, 13, 14, 15 and 16 of player with stained glass pane:7 named "&b" to nothing
        make gui slot 4 of player with sunflower named "&3Toplam Saklanan &bXP" with lore "&8 ▪ &7%{xp::%player%} otherwise 0% &bXP" to nothing
        make gui slot 29 of player with EXP BOTTLE named "&6XP Saklama" with lore "||&eXp'nin &aistediğin kısmını||&esaklamak için buraya tıkla." to run:
            close player's inventory
            send "&8       ▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬ &6&lXP &8▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬"
            send " "
            send "          &bLütfen istediğin &3XP &bsaklama değerini sohbete gir."
            send " "
            send "&8       ▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬ &6&lXP &8▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬▬"
            set {sohbetxp::%player%} to true
            wait 10 seconds
            delete {sohbetxp::%player%}
        make gui slot 31 of player with nether star named "&6XP Geri Alma" with lore "||&eSakladığın XP'yi &ageri||&aalmak &eiçin buraya tıkla." to run:
            if {xp::%player%} is set:
                add {xp::%player%} to xp of player
                delete {xp::%player%}
                close player's inventory
            else:
                send "&6&l FC &8» &eDaha önce hiç XP saklamamışsın."
                close player's inventory
        make gui slot 33 of player with EXP BOTTLE named "&6XP Saklama" with lore "||&eXp'nin &atamamını &esaklamak||&eiçin buraya tıkla." to run:
            add xp of player to {xp::%player%}
            set xp of player to 0
            send "&6&l FC &8» &EXp'nin tamamını başarıyla sakladın."
            close player's inventory

on chat:
    if {sohbetxp::%player%} is set:
        set {_sayı} to message parsed as number
        cancel event
        if {_sayı} is greater than 0:
            if level of player is greater than or equal to {_sayı}:
                set {_xp1} to xp of player
                set level of player to level of player - {_sayı}
                set {_xp2} to xp of player
                add {_xp1} - {_xp2} to {xp::%player%}
                send "&6&l FC &8» &fXp'nin &e%{_sayı}% Level &fkadarını başarıyla sakladın."
                delete {sohbetxp::%player%}
            else:
                send "&6&l FC &8» &eGirilen değer kadar XP'ye sahip değilsin."
        else:
            send "&6&l FC &8» &eLütfen XP değeri için bir sayı giriniz."